Danmakufu Q&A/Problem Thread II

[Helepolis]

Sounds more like a function for stage enemies.

[Kylesky]

Sounds more like a function for stage enemies.

I actually used it for stage enemies


EDIT: I noticed something about Sinuate Lasers... if you make something like this

Code: [Select]

task tentacle
{
let obj=Obj_Create(OBJ_SINUATE_LASER);
Obj_SetPosition(obj, GetX+50*cos(Obj_GetAngle(obj)), GetY+50*sin(Obj_GetAngle(obj)));
Obj_SetSpeed(obj, 10);
Obj_SetAngle(obj, 0);
ObjShot_SetGraphic(obj, BLUE01);
ObjSinuateLaser_SetLength(obj, 100);
ObjSinuateLaser_SetWidth(obj, 20);
while(Obj_BeDeleted(obj)==false)
{
yield;
Obj_SetAngle(obj, Obj_GetAngle(obj)+1);
Obj_SetPosition(obj, GetX+50*cos(Obj_GetAngle(obj)), GetY+50*sin(Obj_GetAngle(obj)));
}
}to make a laser that spins around the boss, the laser appears much thiner than what you declared at ObjSinuateLaser_SetWidth, but the hitbox is a bit larger than the graphic (although still of course smaller than what you declared)... should it really be like this? I have a feeling that this is a stupid question with a really basic explanation to why the laser's like that... (that bit of code actually makes a laser that spins around the boss 50 pixels away, but with a width of about 1 pixel...)

I know that you could just spawn the laser in a different spot to make the same thing, but I'm showing this code because what if you want the laser to continue circling the boss while the boss is moving?... (there's probably a way to do that other than this code, I'm sure...) and actually... if you make the boss move, it generates a normal portion of the laser, but looks really weird in contrast to the other parts that are still 1 pixel thick...

[Hat]

INCOMING HEADACHE

Code: [Select]

#TouhouDanmakufu
#Title[FUCK]
#Text[ASSBALLS]
#Player[FREE]
#ScriptVersion[2]
#BGM[]

script_enemy_main {
#include_function "lib\ExtendedShotDatav4\shot_replace.dnh"
    let ImgBoss = "script\img\ExRumia.png";
let pos_draw_a = GetX;
let f = -120;

task derf{
let angle = rand(0, 360);
ascent(a in 0..30){
CreateShot01(GetX, GetY, 3, angle + a*(360/30), ORANGE12, 10);
}
}

task bamf(let i){
let angle = rand_int(0, 18);
loop(10){
ascent(x in 0..20){
yams(i, angle+x*18);
}
loop(3){yield;}
}
}

task yams(let i, let a){
let a_i = [[GetCenterX-175 , GetCenterY-150],[GetCenterX+175 , GetCenterY-150]];
let obj = Obj_Create(OBJ_SHOT);
Obj_SetPosition(obj, a_i[i][0], a_i[i][1]);
Obj_SetSpeed(obj, 10);
Obj_SetAngle(obj, a);
ObjShot_SetGraphic(obj, RED43);
ascent(b in 0..33){Obj_SetSpeed(obj, 10-b*0.3); yield;}
Obj_SetSpeed(obj, 0);
loop(30){yield;}
Obj_SetSpeed(obj, 2);
loop(60){
let anglep = atan2(GetPlayerY-Obj_GetY(obj), -Obj_GetX(obj)+GetPlayerX);
let angleb = Obj_GetAngle(obj);
if(angleb >= 0){
if(anglep > angleb + 1 || anglep <= angleb - 180){Obj_SetAngle(obj, angleb + 1);}
if(anglep < angleb - 1 && anglep > angleb - 180){Obj_SetAngle(obj, angleb - 1);}
} else if(angleb < 0){
if(anglep < angleb - 1 || anglep > angleb + 180){Obj_SetAngle(obj, angleb - 1);}
if(anglep > angleb + 1 && anglep <= angleb + 180){Obj_SetAngle(obj, angleb + 1);}
} else if(angleb == 0){angleb+=0.1;}
while(angleb > 180){angleb -= 360;}
while(angleb < -180){angleb += 360;}
if(anglep <= angleb+1 && anglep >= angleb-1){Obj_SetAngle(obj, anglep);}
yield;
}
}

    @Initialize {
        SetLife(2000);
SetInvincibility(60);
        SetTimer(99);
        SetScore(1000000);

        SetMovePosition02(GetCenterX, GetClipMinY + 120, 120);
        CutIn(YOUMU, "Yam Sign "\""Attack of the fucking yams"\", "", 0, 0, 0, 0);

        LoadGraphic(ImgBoss);
        SetTexture(ImgBoss);
ShotInit;
    }

    @MainLoop {
        SetCollisionA(GetX, GetY, 32);
        SetCollisionB(GetX, GetY, 16);
if(f%20==0 && f>=0){derf;}
if(f%80==0 && f>=0){bamf(0);}
if(f%85==0 && f>=0){bamf(1);}
f++;
yield;
    }

    @DrawLoop {
if(GetX==pos_draw_a){
SetGraphicRect(0, 0, 64, 64);
        DrawGraphic(GetX, GetY);
}
if(GetX<pos_draw_a){
SetGraphicRect(128, 0, 192, 64);
DrawGraphic(GetX, GetY);
}
if(GetX>pos_draw_a){
SetGraphicRect(192, 0, 256, 64);
DrawGraphic(GetX, GetY);
}
pos_draw_a = GetX;
    }

    @Finalize {
        DeleteGraphic(ImgBoss);
    }
}
Okay. I apologize for the general disorganization and abysmal use of tabbing, but just... try this stupid thing (shot replace v4 required, or you can just change RED43 to whatever). A hitboxless character is strongly advised, or something like that. Anyway. As you can see, my lovely bullets curve towards the player in a highly sensual manner... except for one fun little thing. The first bullet in each wave lags behind the rest by a little, so the 'beams' (which, as it strikes me now, look very shinki-esque) have a little deformity. I've tried everything, and nothing I do can even address the little head. I normally debug my cards by exaggerating various things and seeing what breaks, but I cannot break the head on this at all. It just stays in the same place, and makes the whole card look really shitty.

Obviously, this is a work in progress.

EDIT: It's slightly hard to see in this form, so my suggestion would be to replace RED43 with TEAL12I, and set the loop(30){yield;} in yams() to something much bigger. Maybe to 120? Enough so that you can see, I dunno.

[Blargel]

Quick easy solution: Set the first bullet's alpha to 0 and turn off collision detection to the player.
Hard solution: Figure out what's wrong with your math. :V

[Iryan]

INCOMING HEADACHE
<snip>

OK. I have absolutely no idea why, but after tinkering around, I found that moving the loop(3){yield;} in bamf before the ascent rather than behind it fixes the error.

Code: [Select]

task bamf(let i){
let angle = rand_int(0, 18);
loop(10){
loop(3){yield;}
ascent(x in 0..20){
yams(i, angle+x*18);
}
}
}

[Hat]

\o/

Thanks, Iryan. XD I never thought the problem would be in bamf... -_- Thanks aplenty!

[professor_scissors]

A friend of mine is trying to get Danmakufu to work on 32-bit Windows XP, and is having a bit of a technical problem. Every script, whether it's a single, a plural, or a stage, fatally crashes the game about when it's supposed to give the "Stage Clear" message, every time. This is using scripts that never produce this error on my machine (tested on Vista and on 7). Version is 0.12, any possible solutions?

[KrackoCloud]

How can I create something similar to the lasers in say, Subterrnean Animsim, Stage 3? - Basically, lasers that shoot, stop so you can read them, and then resume moving.

Laser01 has no Set Data function, and sinuates shrink when they stop or slow down.

[Suikama]

Isn't there a Laser0A function?

[Fetch()tirade]

There's CreateLaserA, but not 0A.

[KrackoCloud]

I thought it was only for screen-long lasers, not the bullet-like ones.

[Gc]

Make a basic object laser, set speed, hide source glow ?

[Naut]

Nah, you can use CreateLaserAs, but that may actually be your only option. I'd advise ascenting the SetLaserDataA like this:

CreateLaserA(0, GetX, GetY, 50, 10, RED01, 0);
ascent(j in 0..30){
   SetLaserDataA(0, j, NULL, 0, 0, j*0.2, GetAngleToPlayer);
}
decent(j in 0..30){
   SetLaserDataA(0, 30 + (30 - j), NULL, 0, 0, j*0.1 + 3, GetAngleToPlayer);
}
FireShot(0);

I'm not even sure how Object lasers would work in that regard, but setting an invisible base as well as an angle and speed seems to be an option as well. Plus it's probably less of a headache than the CreateLaserA method, haha!

[Blargel]

Just cause I have nothing better to do, here's the gist of the object version. Tested quickly in Danmakufu. May have some strange bugs if I wasn't careful enough.:

task PausingLaser(x, y, speed, angle, graphic, delay, length, width, timebeforepausing, pausetime){
    // Set up initial values.
    let obj = Obj_Create(OBJ_LASER);
    Obj_SetPosition(obj, x, y);
    Obj_SetAngle(obj, angle);
    ObjShot_SetGraphic(obj, graphic);
    ObjShot_SetDelay(obj, delay);
    ObjLaser_SetLength(obj, 0); // Set length to zero initially so the laser can grow out of the spawn point.
    ObjLaser_SetWidth(obj, width);
    ObjLaser_SetSource(obj, false);
    loop(delay){yield;} // Wait for the delay time.

    // Set up variables to control acceleration and deceleration
    let vel = speed;
    let accel = speed/timebeforepausing * -1;

    // Grow the laser out of the start position
    while(ObjLaser_GetLength(obj)<length){
        ObjLaser_SetLength(obj, ObjLaser_GetLength(obj)+vel);
        // Some extra logic to pause the laser while it's growing if the pause time happens in
        // this while loop and make the speed not accelerate past the original speed.
        if(vel<=speed){
            vel += accel;
        }
        if(vel<=0){
            loop(pausetime){yield;}
            accel *= -1;
        }
        yield;
    }
    ObjLaser_SetLength(obj, length);
    while(!Obj_BeDeleted(obj)){
        Obj_SetPosition(obj, Obj_GetX(obj)+cos(angle)*vel, Obj_GetY(obj)+sin(angle)*vel);
        if(vel<=speed){
            vel += accel;
        }
        if(vel<=0){
            loop(pausetime){yield;}
            accel *= -1;
        }
        yield;
    }
}

[Louchan]

Hello, I'm new here and to Danmakufu as well, and I would like some help.
I just got Danmakufu from the official website and I've changed my computer's language to Japanese, but the program just won't work. It crashes as soon as I start it. What's wrong?

[Hat]

What's your computer's specs? Sometimes it haet older computer models.

Also, try using Applocale. It saves headaches in the long run. Google it, it's a microsoft thing.

[Blargel]

My advice is to change your computer's language back to English (or whatever language you usually use) and follow the advice in the AppLocale Tutorial.

[Demonbman]

Is there a way to have Obj Bullets bounce off other bullets not of that id?

[Naut]

Yes? ID should not matter.

let obj = Obj_Create(OBJ_SHOT);
ObjectArray = ObjectArray ~ [obj];

//...etc;

while(!Obj_BeDeleted(obj)){
   ascent(j in 0..length(ObjectArray)){
      if(Collision_Obj_Obj(obj, j)){
         //do shit;
      }
   }
yield;
}

[Fetch()tirade]

When attempting to create a shot and or laser that would bounce off the walls several times before disappearing, is it easier to change the angle of the shot using Obj_SetAngle or just making another shot entirely? Here's a sample of the code below, where the shot changes once before leaving the screen.

   task lolshot(x,y,v,dir,graphic,delay){
      let obj = Obj_Create(OBJ_SHOT);

      Obj_SetPosition(obj,x,y);
      Obj_SetSpeed(obj,v);
      Obj_SetAngle(obj,dir);
      ObjShot_SetGraphic(obj,graphic);
      ObjShot_SetDelay(obj,delay);
      ObjShot_SetBombResist(obj,true);

      while(!Obj_BeDeleted(obj)){
         if(Obj_GetY(obj) < GetClipMinY){
            CreateShot01(Obj_GetX(obj),Obj_GetY(obj),3,atan2(-sin(Obj_GetAngle(obj)),cos(Obj_GetAngle(obj))),AQUA23,0);
            Obj_Delete(obj);
         }
         if(Obj_GetY(obj) > GetClipMaxY){
            CreateShot01(Obj_GetX(obj),Obj_GetY(obj),3,atan2(-sin(Obj_GetAngle(obj)),cos(Obj_GetAngle(obj))),AQUA23,0);
            Obj_Delete(obj);
         }
         if(Obj_GetX(obj) < GetClipMinX){
            CreateShot01(Obj_GetX(obj),Obj_GetY(obj),3,atan2(sin(Obj_GetAngle(obj)),-cos(Obj_GetAngle(obj))),AQUA23,0);
            Obj_Delete(obj);
         }
         if(Obj_GetX(obj) > GetClipMaxX){
            CreateShot01(Obj_GetX(obj),Obj_GetY(obj),3,atan2(sin(Obj_GetAngle(obj)),-cos(Obj_GetAngle(obj))),AQUA23,0);
            Obj_Delete(obj);
         }
         yield;

      }
   }

In this excerpt, the shots are changing direction as expected, but they aren't disappearing. I can't set the kill time arbitrarily, so what do I do? I'm looking for four bounces.

   task lolshot(x,y,v,dir,graphic,delay){
      let obj = Obj_Create(OBJ_SHOT);

      Obj_SetPosition(obj,x,y);
      Obj_SetSpeed(obj,v);
      Obj_SetAngle(obj,dir);
      ObjShot_SetGraphic(obj,graphic);
      ObjShot_SetDelay(obj,delay);
      ObjShot_SetBombResist(obj,true);

      while(!Obj_BeDeleted(obj)){
         if(Obj_GetY(obj) < GetClipMinY){
            Obj_SetAngle(obj,atan2(-sin(Obj_GetAngle(obj)),cos(Obj_GetAngle(obj))));
         }
         if(Obj_GetY(obj) > GetClipMaxY){
            Obj_SetAngle(obj,atan2(-sin(Obj_GetAngle(obj)),cos(Obj_GetAngle(obj))));
         }
         if(Obj_GetX(obj) < GetClipMinX){
            Obj_SetAngle(obj,atan2(sin(Obj_GetAngle(obj)),-cos(Obj_GetAngle(obj))));
         }
         if(Obj_GetX(obj) > GetClipMaxX){
            Obj_SetAngle(obj,atan2(sin(Obj_GetAngle(obj)),-cos(Obj_GetAngle(obj))));
         }
         yield;

      }
   }

[Naut]

   task lolshot(x,y,v,dir,graphic,delay){
      let obj = Obj_Create(OBJ_SHOT);
     
      let counter = 0;

      Obj_SetPosition(obj,x,y);
      Obj_SetSpeed(obj,v);
      Obj_SetAngle(obj,dir);
      ObjShot_SetGraphic(obj,graphic);
      ObjShot_SetDelay(obj,delay);
      ObjShot_SetBombResist(obj,true);

      while(!Obj_BeDeleted(obj)){
         if(counter<4){
            if(Obj_GetY(obj) < GetClipMinY){
               let position = GetClipMinY - Obj_GetY(obj);
               Obj_SetY(obj, GetClipMinY + position);
               Obj_SetAngle(obj, 0 - Obj_GetAngle(obj));
               counter++;
            }
            if(Obj_GetY(obj) > GetClipMaxY){
               let position = Obj_GetY(obj) - GetClipMaxY;
               Obj_SetY(obj, GetClipMaxY - position);
               Obj_SetAngle(obj, 0 - Obj_GetAngle(obj));
               counter++;
            }
            if(Obj_GetX(obj) < GetClipMinX){
               let position = GetClipMinX - Obj_GetX(obj);
               Obj_SetY(obj, GetClipMinX + position);
               Obj_SetAngle(obj, 180 - Obj_GetAngle(obj));
               counter++;
            }
            if(Obj_GetX(obj) > GetClipMaxX){
               let position = Obj_GetX(obj) - GetClipMaxX;
               Obj_SetY(obj, GetClipMaxX - position);
               Obj_SetAngle(obj, 180 - Obj_GetAngle(obj));
               counter++;
            }
            yield;
         }
      }
   }

Fixed your reflecting code too, you needed to make up for the distance the bullet may have passed the clip, for a true "reflection". Also, I replaced your reflection calculations with a much more simplistic version.

[Fetch()tirade]

lol

Tried it. It crashed. Not only that, the shots didn't bounce. I'll come back to this later, I guess.

[durdur]

Hello ^^ i have a question: what can be done about lag while running scripts with danmakufu? in some cases (mainly during stages) the fps lowers to almost 20 ;_; Is there a way to improve this besides migrating to another computer?

Thanks in advance, again~ 

[Drake]

If it happens frequently then you probably should move to another computer anyways...

Open up config.exe, and wherever the 1/2 and 1/3 are, click one of those. It should speed things up, even if it starts looking a tad choppy.

[Tarokarr]

Code: [Select]

task lolshot(x,y,v,dir,graphic,delay){
let obj = Obj_Create(OBJ_SHOT);
     
let counter = 0;

Obj_SetPosition(obj,x,y);
Obj_SetSpeed(obj,v);
Obj_SetAngle(obj,dir);
ObjShot_SetGraphic(obj,graphic);
ObjShot_SetDelay(obj,delay);
ObjShot_SetBombResist(obj,true);

while(!Obj_BeDeleted(obj)){
if(counter<4){
if(Obj_GetY(obj) < GetClipMinY){
let position = GetClipMinY - Obj_GetY(obj);
Obj_SetY(obj, GetClipMinY + position);
Obj_SetAngle(obj, 0 - Obj_GetAngle(obj));
counter++;
}
if(Obj_GetY(obj) > GetClipMaxY){
let position = Obj_GetY(obj) - GetClipMaxY;
Obj_SetY(obj, GetClipMaxY - position);
Obj_SetAngle(obj, 0 - Obj_GetAngle(obj));
counter++;
}
if(Obj_GetX(obj) < GetClipMinX){
let position = GetClipMinX - Obj_GetX(obj);
Obj_SetX(obj, GetClipMinX + position);
Obj_SetAngle(obj, 180 - Obj_GetAngle(obj));
counter++;
}
if(Obj_GetX(obj) > GetClipMaxX){
let position = Obj_GetX(obj) - GetClipMaxX;
Obj_SetX(obj, GetClipMaxX - position);
Obj_SetAngle(obj, 180 - Obj_GetAngle(obj));
counter++;
}
}
yield;
}
}
fixed the yield: don't just yield in an if-statement inside a while-loop  :V
fixed the borders: Use SetX-Functions for GetClipMaxX and GetClipMinX.

And btw... Hi to all, I guess?

[Naut]

S'what I get for not testing the code

[Louchan]

What's your computer's specs? Sometimes it haet older computer models.

Also, try using Applocale. It saves headaches in the long run. Google it, it's a microsoft thing.

Windows Vista Home Premium.
... Um, I'm not sure what else to write down.

My advice is to change your computer's language back to English (or whatever language you usually use) and follow the advice in the AppLocale Tutorial.

Okay, I'll try it out.

[Nimono]

Windows Vista Home Premium.
... Um, I'm not sure what else to write down.

Try right-clicking the .exe and selecting Run as Administrator, if the option appears on Vista. It does for 7, where the game also crashes if you try to run it normally, but running as Administrator seems to always fix it. But of course, I've never truly used Vista, so I don't know if that option is there...

[Lawence Codye]

Try right-clicking the .exe and selecting Run as Administrator, if the option appears on Vista. It does for 7, where the game also crashes if you try to run it normally, but running as Administrator seems to always fix it. But of course, I've never truly used Vista, so I don't know if that option is there...

it does exist...I use Vista Home Premium so I know this helps it work, however Applocale is needed for it to run at all on Vista Home Premium.

[Kylesky]

Does anyone know what Danmakufu returns when you divide a number by 0? I'm just curious... Doubt this'll really be of any use... I tried doing something like:

frame++;
if(frame==100/0)
{
do stuff;
}

nothing happens