※ Q&A/Problem Thread 5 ※ for OLD Danmakufu version (0.12m)

[Darkness1]

Random question: what is the main difference between tasks, functions and subs?

[Azure Lazuline]

A function is a piece of code that you can basically shortcut to, and it accepts parameters. A very basic example:

Code: [Select]

@MainLoop{
  NewShot(GetAngleToPlayer);
}

function NewShot(angle){
  CreateShot01(GetX,GetY,3,angle,RED01,0);
}

Since NewShot is called with GetAngleToPlayer as the first parameter, that's where the shot will be fired. You can make the function as long as you want and with as many parameters as you want, so they can serve as a great shortcut. Functions can also return values, like this:

Code: [Select]

function BossAngleToPoint(x,y){
  return atan2(y-GetY,x-GetX);
}

which would return the angle from the boss to point x,y, which you would call with, for example, BossToPoint(GetPlayerX,GetPlayerY) and it would return the same thing as GetAngleToPlayer (and would be used in the same way).

A sub is the exact same thing as a function, but it can't accept parameters and can't return values. Its only purpose is that it's slightly faster.

A task is also like a function, but it can be delayed for a frame with the yield; command (assuming there's also a yield; in MainLoop). It can't return values, though. It's the most powerful of the three, and lets you do lots of things that the others can't do easily. For examples, there's several tutorials on tasks, so I won't get into too much detail here.

[KrackoCloud]

I used to have a hard time understanding that stuff too. Here's my attempt at simplifying things.

Sub : Does one thing.
Like "Do the laundry for your dark clothes."

Function : Does one thing, with parameters.
"Do the laundry. Which type of clothing?"
Functions are useful because they can return results to your code. For example, if you had to add 12 to variables x, y, and z all the time, you could just make a function called PlusTwelve. Tell the function to add 12 to whatever you put in its parameters - Then you could call PlusTwelve(x), PlusTwelve(y), and PlusTwelve(z) wherever necessary!
Of course, functions can do a lot more than simple addition. The things some people around here can do with functions are crazy.

Task : Does something, but through things like 'Yield,' you can make it act like a loop that works alongside MainLoop.
"Do the laundry while listening to radio."
You can still keep parameters.
If you wanted to shoot three different patterns at the same time, you could just make three tasks. This makes the code easier to understand, less cluttered, and less likely for the different attacks' scriptings to get in the way of each other.
Tasks are probably more versatile than this, but I find this is the most common use.

[Blargel]

Task : Does something, but through things like 'Yield,' you can make it act like a loop that works alongside MainLoop.
"Do the laundry while listening to radio."
You can still keep parameters.
If you wanted to shoot three different patterns at the same time, you could just make three tasks. This makes the code easier to understand, less cluttered, and less likely for the different attacks' scriptings to get in the way of each other.
Tasks are probably more versatile than this, but I find this is the most common use.

This is pretty misleading, actually. Generally, a task is a function with the ability to pause at any time for a frame with yield. Here's a more practical example related to danmaku.

Sub: "Shoot a ring of 20 bullets when I tell you to."
It will always be 20 bullets at the same speed, angles, graphic, etc. Nothing will change at all (unless you're using rand somewhere in your sub but that's beside the point).

Code: [Select]

sub ShootRing {
    ascent(i in 0..20){
        CreateShot01(GetX, GetY, 3, i*18, RED01, 0);
    }
}
Function: "Shoot a ring of bullets when I tell you to. I'm going to tell you how many bullets are in the ring when I tell you to shoot them."
It will shoot however many bullets you tell it to shoot. If you wanted, you could add more things to change angle, speed, and/or graphic too.

Code: [Select]

function ShootRing(num){
    ascent(i in 0..num){
        CreateShot01(GetX, GetY, 3, i*(360/num), RED01, 0);
    }
}
Function: "Add two numbers together when I tell you to. I'm going to tell you what the numbers are when I tell you to add them. Also, tell me what the result is."
The other feature of a function is that it can return things. In this case you could put let something = AddNumbers(1, 2); and it would run the function with those two inputs and return result which is 3.

Code: [Select]

function AddNumbers(a, b){
    let result = a + b;
    return result;
}
Task: "Wait a second and then shoot a ring of bullets when I tell you to. I'm going to tell you how many bullets are in the ring when I tell you to shoot them."
The only thing unique about a task is that, unlike functions, it can wait between any of its commands. Otherwise, it behaves just like a function without the ability to return stuff. By the way, make sure @MainLoop has a single yield that is run every frame if you plan to use tasks. Otherwise the yields in tasks will not work properly.

Code: [Select]

task ShootRing(num){
    loop(60){ yield; } // Every yield makes it wait 1 frame so 60 frames of waiting is 1 second.
    ascent(i in 0..num){
        CreateShot01(GetX, GetY, 3, i*(360/num), RED01, 0);
    }
}

[KrackoCloud]

I figured I was wrong when it came to the technical definition, it's just that for the sake of a beginner, I was trying to focus on using it like some sort of loop.
But yeah, it definitely wasn't a very complete or correct view of things now that you mention it. I think your explanation's the best one.

[BardzoSkomplikowanyNick]

Excuse me, could somebody explain how to make Sanae's stars pattern?

Something like this or stars like in Takeminataka Invocation.

[theblainer81]

Hi everyone,
I'm having a little problem here with a task again.
I just want to change the size of my bullet, so I use ObjLaser_SetLength and ObjLaser_SetWidth.
But I had to change my object to a OBJ_LASER, so my bullet isn't moving anymore. Because a laser isn't supposed to move I think.
I tried to to put a Obj_SetPosition and changing the size manually in my while(Obj_BeDeleted(obj)==false), but it kinds of failed.

My code is

Code: [Select]

let obj=Obj_Create(OBJ_LASER);
let nb = 30;
let nbframe = 0;

Obj_SetPosition(obj, x, y);
Obj_SetSpeed(obj, v);
Obj_SetAngle(obj, angle);
ObjLaser_SetLength(obj,100);
ObjLaser_SetWidth(obj,50);
ObjLaser_SetSource(obj,true);
ObjShot_SetGraphic(obj, WHITE03);
ObjShot_SetDelay(obj, 1);
ObjShot_SetBombResist(obj, true);Can some help me to make my bullet with the size I want move, please?

[Something XutaWoo-y]

Code: [Select]

Obj_SetPosition(obj, Obj_GetX(obj)+cos(angle)*v, Obj_GetY(obj)+sin(angle)*v));
Probably what you're looking for.

[CK Crash]

Code: [Select]

Obj_SetPosition(obj, Obj_GetX(obj)+cos(angle)*v, Obj_GetY(obj)+sin(angle)*v);
Probably what you're looking for.

I think you had an extra parenthesis. To elaborate further, laser objects ignore the object-specific speed parameter, so you must set the position manually each frame using the above line. Basically, put it in the while(!Obj_BeDeleted(obj)){} part of the task. If you want to use the speed parameter in the same way as an object bullet, then use:

Code: [Select]

Obj_SetPosition(obj, Obj_GetX(obj)+cos(angle)*Obj_GetSpeed(obj), Obj_GetY(obj)+sin(angle)*Obj_GetSpeed(obj));
If your laser's movement angle and actual angle are the same, then you may also want to use the angle parameter instead of a variable to simplify things. In this case:

Code: [Select]

Obj_SetPosition(obj, Obj_GetX(obj)+cos(Obj_GetAngle(obj))*Obj_GetSpeed(obj), Obj_GetY(obj)+sin(Obj_GetAngle(obj))*Obj_GetSpeed(obj));
(on a side note I edited this post like 4 times because I mixed up the code woopsies)

[Darkness1]

I followed Helepolis video tutorials on how to animate bosses, and that's how i do it now.

Like:

Code: [Select]

If GetSpeedX>0{//A bunch of SetGraphicRect codes}
But what if i want to animate attack sprites, and animate through them only when the boss does a certain move/attack? How would a task (or something else) for that look like?

[Naut]

But what if i want to animate attack sprites, and animate through them only when the boss does a certain move/attack? How would a task (or something else) for that look like?

Something like this:

let attacking = false;
let frame = 0;

@MainLoop{
   frame++;
   if(frame==50){
      attacking = true;
   }else if(frame==60){
      ascent(i in 0..36){
         CreateShot01(GetX, GetY, 3, i*10 + GetAngleToPlayer, RED01, 0);
      }
      attacking = false;
      frame = 0;
   }
}

@DrawLoop{
   SetTexture(boss);
   if(attacking){
      SetGraphicRect(192, 0, 255, 63);
   }else if(GetSpeedX>0){
      SetGraphicRect(64, 0, 127, 63);
   }else if(GetSpeedX<0){
      SetGraphicRect(128, 0, 191, 63);
   }else{
      SetGraphicRect(0, 0, 63, 63);
   }
   DrawGraphic(GetX, GetY);
}

[Blargel]

I followed Helepolis video tutorials on how to animate bosses, and that's how i do it now.

Like:

Code: [Select]

If GetSpeedX>0{//A bunch of SetGraphicRect codes}
But what if i want to animate attack sprites, and animate through them only when the boss does a certain move/attack? How would a task (or something else) for that look like?

Or you can save yourself some headache and use my animation library[/self-plug]. Just take a look at the comments in the library itself and how the example file that is included uses the functions. You can always ask questions about it here or send a PM if you want help using it.

Excuse me, could somebody explain how to make Sanae's stars pattern?

Something like this or stars like in Takeminataka Invocation.

This is a bit much to explain but in general, to make a 5 pointed star, you need to make 5 points equally spaced in a circle around the center point and then connect them. I don't know how much trigonometry you're comfortable with so I'm not sure where to start explaining. For now, let's say you chose the point (cx, cy) as the center of the star and a size of s. The top point of the star would be (cx+cos(-90)*s, cy+sin(-90)*s). If you add 144 to the angle in the sin and cos functions, you will find one of the two points that the top point needs to draw a line to. Keep adding 144 to that angle until you reach the top again while connecting the points in the order you find them and you'll find that you created a star.

[TheTeff007]

I'm trying to make a single effect object to appear, and when I run the script, it runs normally but the effect doesn't shows up even when I called for it.

Maybe I'm doing something wrong with the vertex or something? I followed Helepolis Tutorial strictly and I didn't managed to make an effect object. Here's the code:

Code: [Select]

task effect{
let obj = Obj_Create(OBJ_EFFECT);
let counter = 0;


ObjEffect_SetRenderState(obj,ALPHA);
ObjEffect_SetTexture(obj, Eff);

Obj_SetPosition(obj, GetCenterX,100);
ObjEffect_SetScale(obj, 1, 1);
ObjEffect_SetLayer(obj, 8);

ObjEffect_SetPrimitiveType(obj, PRIMITIVE_TRIANGLESTRIP);
ObjEffect_CreateVertex(obj, 4);

ObjEffect_SetVertexXY(obj, 0, -276, -31);
ObjEffect_SetVertexXY(obj, 1, 276, -31);
ObjEffect_SetVertexXY(obj, 2, -276, 31);
ObjEffect_SetVertexXY(obj, 3, 276, 31);

ObjEffect_SetVertexUV(obj, 0, 0, 0);
ObjEffect_SetVertexUV(obj, 1, 552, 0);
ObjEffect_SetVertexUV(obj, 2, 0, 62);
ObjEffect_SetVertexUV(obj, 3, 552, 62);

while(!Obj_BeDeleted(obj)){

if(counter==120){ Obj_Delete(obj); }
counter++;
yield;
}
}

[theblainer81]

Thank you so much Lucas!!
It worked the first time I execute the script and that's beautiful!

[BardzoSkomplikowanyNick]

This is a bit much to explain but in general, to make a 5 pointed star, you need to make 5 points equally spaced in a circle around the center point and then connect them. I don't know how much trigonometry you're comfortable with so I'm not sure where to start explaining. For now, let's say you chose the point (cx, cy) as the center of the star and a size of s. The top point of the star would be (cx+cos(-90)*s, cy+sin(-90)*s). If you add 144 to the angle in the sin and cos functions, you will find one of the two points that the top point needs to draw a line to. Keep adding 144 to that angle until you reach the top again while connecting the points in the order you find them and you'll find that you created a star.

Thanks.

But is it for lasers or bullets?
Is it need angle?

[Blargel]

I'm trying to make a single effect object to appear, and when I run the script, it runs normally but the effect doesn't shows up even when I called for it.

Maybe I'm doing something wrong with the vertex or something? I followed Helepolis Tutorial strictly and I didn't managed to make an effect object. Here's the code:

Code: [Select]

task effect{
let obj = Obj_Create(OBJ_EFFECT);
let counter = 0;


ObjEffect_SetRenderState(obj,ALPHA);
ObjEffect_SetTexture(obj, Eff);

Obj_SetPosition(obj, GetCenterX,100);
ObjEffect_SetScale(obj, 1, 1);
ObjEffect_SetLayer(obj, 8);

ObjEffect_SetPrimitiveType(obj, PRIMITIVE_TRIANGLESTRIP);
ObjEffect_CreateVertex(obj, 4);

ObjEffect_SetVertexXY(obj, 0, -276, -31);
ObjEffect_SetVertexXY(obj, 1, 276, -31);
ObjEffect_SetVertexXY(obj, 2, -276, 31);
ObjEffect_SetVertexXY(obj, 3, 276, 31);

ObjEffect_SetVertexUV(obj, 0, 0, 0);
ObjEffect_SetVertexUV(obj, 1, 552, 0);
ObjEffect_SetVertexUV(obj, 2, 0, 62);
ObjEffect_SetVertexUV(obj, 3, 552, 62);

while(!Obj_BeDeleted(obj)){

if(counter==120){ Obj_Delete(obj); }
counter++;
yield;
}
}

I'm going to take a wild guess and say that you didn't load the graphic, because I see nothing wrong with your code. :wat:

[TheTeff007]

I did load the graphic, but the image doesn't shows up.

http://pastebin.com/cGbFnffK

There's the whole code

[Chronojet ⚙ Dragon]

You're missing a yield; in your @MainLoop - therefore your code will never run the effect object task! No wonder.

Edit: if you've done that and it still doesn't work, check your file name and pathing.

[Darkness1]

Or you can save yourself some headache and use my animation library[/self-plug]. Just take a look at the comments in the library itself and how the example file that is included uses the functions. You can always ask questions about it here or send a PM if you want help using it.

Wow thanks, this must be the most handy thing for danmakufu I've ever seen!

EDIT: gotta thank OnTheNet too for the Obj_Laser script, really handy.

[theblainer81]

Hi everyone
I'm having a little headache trying to make something.
What I want to do is to shoot a bullet (RED03) and other bullets that would be always behind this bullet even if the angle of the bullet(RED03) is different.
I'm trying to make Math that I learned many years ago : the triangle with a^2 + b^2 = c^2 and also sin(angle) = opp. / hyp. or tan(angle) = opp. / adj. . You know math from high scool.
All this to try making bullets always behind my big bullet that the boss is shooting. The result is not really working but I sense that I'm not so far from the real answer to my problem.

But does anyone can help me figure this out?
Please

[Drake]

Gonna need to head into simple circle trig if you want to do this stuff!

In any case, do you mean making like a snake of bullets? I'm not entirely understanding what you want to do.

[theblainer81]

For my problem to make a "snake" of bullets,
After several times, I have this code for my Mainloop

Code: [Select]

@MainLoop
{
   SetCollisionA(GetX, GetY, 32);
   SetCollisionB(GetX, GetY, 16);
   if(frame == 100)
   {
frame = 0;
CreateShot02(GetX,GetY,2,GetAngleToPlayer,0.05,vitessemax,RED03,0);
CreateShot02(GetX + (sin(GetAngleToPlayer - 180) * 20),GetY + (cos(GetAngleToPlayer - 180) * 20), vitessemin, GetAngleToPlayer, 0.05, vitessemax, RED01, 0);
}
frame++;
}
It doesn't do what I want. My little bullet isn't always behind my big bullet, only when I'm at a certain spot on the screen.
Can anyone help me with that?

[Darkness1]

Where do i get the graphics for rumias StB darkness? Or do i create it's look in another way?

[Drake]

[Blargel]

For my problem to make a "snake" of bullets,
After several times, I have this code for my Mainloop

Code: [Select]

@MainLoop
{
   SetCollisionA(GetX, GetY, 32);
   SetCollisionB(GetX, GetY, 16);
   if(frame == 100)
   {
frame = 0;
CreateShot02(GetX,GetY,2,GetAngleToPlayer,0.05,vitessemax,RED03,0);
CreateShot02(GetX + (sin(GetAngleToPlayer - 180) * 20),GetY + (cos(GetAngleToPlayer - 180) * 20), vitessemin, GetAngleToPlayer, 0.05, vitessemax, RED01, 0);
}
frame++;
}
It doesn't do what I want. My little bullet isn't always behind my big bullet, only when I'm at a certain spot on the screen.
Can anyone help me with that?

Switch your sin and cos. Cos goes with x and sin goes with y.

[theblainer81]

Thanks a lot Blargel!!
I can't believe that I was so close to resolve my problem myself.

[rogus247]

Ok, so recently i watched a video showing how to make good spell cards. I copied his stuff and found it doesnt work on my end for some reason...i keep getting a script error that says somewhere here, i have an error:

task mainTask{
      wait(120);
      yield;
      movement;
   }

   task movement{

      loop{
         SetMovePositionRandom01(60,30,10,GetCenterX-120,GetCenterY-100,GetCenterX+120,GetCenterY-40);
         wait(30);
         SetColor(128,128,255);
         Concentration01(80);
         SetColor(255,255,255);
         wait(30);
         fire;
         wait(180);
         yield;
      }

   }

Im not sure if giving just this is enough though...if anyone could fix my script, that would be great! Just message me if you need my script! Thanks!

-Rogus

[Naut]

We need to know the error you got. Screenshot or copy/paste it.

[rogus247]

How do i put an image? (sorry, new here. xD)

[Blargel]

How do i put an image? (sorry, new here. xD)

First off, welcome to Rika's Garage!

Judging from your question you might be new to forums in general as well so just in case let me give you a quick pointer. Read the stickies. They're at the top for a reason. The one most of us hope new people like yourself notice is the one that says "※ The GREAT information thread ※ READ THIS OR SCIENCE WILL END YOU". In it, you'll find a bunch of resources related to Danmakufu as well as some general rules to follow while posting here to keep things nice and tidy. This includes some links to various tutorials for commonly asked questions such as drawing an image or making specific patterns of bullets. In my opinion, newbies should start by reading the basic tutorial unless you have some experience in programming or scripting in another language.